Исходный код

'Запустить TDMS из внешнего приложения, например, из редактора скриптов любого
'приложения MS Office. Внимание: должна быть подключена библиотека типов
'TDMS (Tools -> References -> TDMS 3.0 Type Library).


'==============================================================================
'Тестовый вызов функции CreateTDMSApp(): открыть приложение с заданными параметрами
'==============================================================================
Sub Test()
    Dim TDMSApp As TDMSApplication
    
    Set TDMSApp = CreateTDMSApp("SYSADMIN", , "DBtest", "(local)")
    MsgBox "Версия приложения TDMS: " & TDMSApp.Version
End Sub


'==============================================================================
'Функция создает экземпляр приложения TDMS и выполняет фоновый вход в систему с
'параметрами, переданными в списке аргументов.

'Возвращаемое значение: ссылка на экземпляр TDMS
'==============================================================================
Function CreateTDMSApp(Optional UserName, Optional UserPass, Optional DBName, _
        Optional ServName, Optional DBType, Optional AuthType) As TDMSApplication
    On Error Resume Next
    Dim TDMSApp As TDMSApplication
    
    Set CreateTDMSApp = Nothing
    
    'Сначала проверяем, не было ли уже запущено приложение. Дело в том, что в этом
    'случае CreateObject() вернет ссылку на существующий экземпляр, и метод Login()
    'вызовет ошибку.
    Set TDMSApp = GetObject(, "TDMS.Application")
    
    If (TDMSApp Is Nothing) = True Then
        'Создать новый объект TDMS.Application
        Set TDMSApp = CreateObject("TDMS.Application")
        'Выполнить вход в систему
        TDMSApp.login UserName, UserPass, DBName, ServName, DBType, AuthType
        'Открыть главное окно приложения
        TDMSApp.Visible = True
    End If

    
    'Вернуть ссылку на созданный экземпляр приложения
    Set CreateTDMSApp = TDMSApp
    Set TDMSApp = Nothing
End Function
'==============================================================================