Исходный код

Option Explicit
Call AddFileDialog(ThisObject)

'============================================================================== 
'Добавить к объекту файлы, используя TDMSAddFileDialog 
'============================================================================== 
Sub AddFileDialog(Object)
  Dim afDlg, bRetVal, intFlag, myXL

  'посмотреть, есть у объекта файлы или нет
  intFlag = Object.Files.Count

  ' Инициализировать и открыть диалог
  Set afDlg = ThisApplication.Dialogs.AddFileDlg
  afDlg.Object = Object

  ' Включаем собственный обработчик ошибок выполнения
  On Error Resume Next

  ' Проверяем, запущено ли приложение Microsoft Excel
  ' Функция GetObject вернет нам ссылку на приложение Excel, если оно запущено
  ' или ошибку, если приложение не запущено
  Set myXL = Getobject(, "Excel.Application")
  If Err.Number <> 0 Then
    ' Сбрасываем ошибку и ничего не делаем
    Err.Clear
  Else
    ' Привязываем диалог открытия файла к отрытому приложению Microsoft Excel
    afDlg.ParentWindow = myXL.Application.hwnd
  End If

  ' Отключаем собственный обработчик ошибок выполнения
  On Error GoTo 0   

  bRetVal = afDlg.Show
  If bRetVal <> TRUE Then
    Exit Sub
  End If

  'Если диалог не был отменен...
  MsgBox "Добавлено файлов к объекту: " & afDlg.Files.Count

End Sub
'==============================================================================